Decodificadores de CATV - Funcionamiento

Estado
Cerrado para nuevas respuestas.

------------------------------------------------------------------------------
IMPORTANTE: El siguiente material Aquí expuesto está destinado al aprendizaje de Normas y Sistemas de Codificación/Decodificación generalmente utilizados en los Sistemas CATV, siendo de esta forma con un fin meramente DIDACTICO. No obstante se ha limitado en dicha publicación los métodos Actuales utilizados por las principales compañias de TV por Cable. Foros de Electrónica no se responsabiliza por el uso inadecuado de la presente información.

Advertencia:
La ley prohibe la fabricación de decodificadores con fines comerciales.
Este proyecto fue creado exclusivamente con fines educativo y experimentales,
de ninguna manera el circuito puede ser comercializado.
Dicho esto, el autor no se hace responsable de ninguna forma de las acciones de los lectores.


Fuente : Digitalman - redigitalman[arroba]usa.net

TEMA: Decodificador de video.
AUTOR: Digitalman

IMAGENES ILUSTRATIVAS : se han omitido hasta resolver host.
Link Download Completo : se ha omitido hasta resolver host.

------------------------------------------------------------------------------


- Objetivos.
- Introducción.

Capitulo 1: La norma Pal-N.

1.1 - Descripción general.
1.2 - Características de la señal de video.
1.3 - Detalles del sincronismo de línea.
1.4 - Detalles del sincronismo de campo.

Capitulo 2: La codificación actual.

2.1 - Codificación del sincronismo horizontal.
2.2 - Inversión aleatoria de video.
2.3 - Codificación del sincronismo vertical.
2.4 - Señalización de control.
2.5 - Codificación del audio.

Capitulo 3: Diseño de la etapa decodificadora.

3.1 - Sincronización de cuadro.
3.2 - Rutina principal.
3.3 - Creación del cuadro.
3.4 - Inserción de línea.
3.5 - Resincronización de línea.
3.6 - Retroceso vertical.
3.7 - Drivers Entrada/Salida.
3.8 - Control de inversión.
3.9 - Habilitación de la etapa.

Capitulo 4:

4.1 - Decodificador de audio.
4.2 - Modificación del control automático de ganancia.
4.3 - Conexionado y calibración.
4.4 - Circuitos electrónicos.
4.5 - Listado de componentes.
4.6 - Descripción de variables y puertos.
4.7 - Software.
4.8 - Serigrafía.

- Conclusión.

Apéndice: Hojas de datos de los integrados utilizados.

Objetivos

El proyecto tiene como objetivos el diseño y realización de una etapa decodificadora, tanto de video como de audio, que cumpla los siguientes requisitos:

* Bajo costo.
* Reducido tamaño.
* Fácil calibración.
* Fácil instalación.


Introducción

Desde hace ya un tiempo en nuestro país, los sistemas de cable han comenzado con la transmisión de canales en forma codificada.
Estos canales son generalmente utilizados para la transmisión de estrenos cinematográficos, eventos deportivos en vivo o programación para adultos, debiéndose pagar un plus adicional al abono mensual para la contratación de los mismos.
Los métodos de codificación utilizados han ido cambiando y perfeccionándose con el tiempo, yendo desde la simple inserción de una señal interferente hasta el sistema de codificación actual, siendo éste sin duda el ultimo paso en cuanto a codificación analógica respecta.
El sistema actual consta de 4 métodos trabajando en forma simultánea y aleatoria, de forma tal, que la imagen codificada sea lo menos discernible posible. Por otro lado, el canal de audio también es “codificado” por el sistema, evitando totalmente su audición.
En sistemas posteriores a este, la transmisión y codificación del video se realiza en forma digital (DirecTV, Sky , Nagravisión, etc.).
El proyecto a desarrollar consiste en una etapa decodificadora (video y audio) que pueda ser instalada en forma directa entre la videograbadora y el televisor.
A modo de unificar términos comenzare por describir como es una señal de tv PAL-N estandart, luego y en forma detallada, describiré como la señal es codificada, para poder así abordar sin problemas el diseño de la etapa decodificadora.

La norma Pal-N


1.1- Descripción general.

La norma Pal-N es la utilizada en nuestro país para la transmisión de señales televisivas, según lo establece esta norma, el displayado de cuadros(imagen completa en pantalla)es realizado 25 veces por segundo. Cada cuadro esta constituido por 2 campos, cada uno de estos consta de 312.5 líneas horizontales, que son trazadas de izquierda a derecha y de arriba hacia abajo a una tasa de 15625 líneas por segundo.
Para combinar efectivamente ambos campos y conformar así un cuadro de 625 líneas se utiliza la técnica de barrido entrelazado, pulsos de pre y pos-ecualización posibilitan su correcta implementación. Esta inteligente técnica posibilita la visualización y refresco de 50 campos por segundo, evitando parpadeos o saltos apreciables, pero lo mas importante es que posibilita el barrido de las 625 líneas con excelente resolución y utilizando solo la mitad del ancho de banda que utilizaría el método no entrelazado.
Para su transmisión, las señales de video son previamente moduladas, una señal de video modulada es comparable con su “demodulada” así como las señales de audio moduladas y demoduladas lo son.

Posteriormente, estas señales al ser sintonizadas por un tv o vcr, son procesadas (demoduladas) recuperando lo que se denomina señal en banda base(Fig.4), generalmente disponibles al usuario a través de conectores RCA.
Es importante resaltar esto ya que a lo largo del proyecto se hará referencia a la señal Pal demodulada(banda base).
El voltaje de una señal en banda base es medido en unidades de IRE, donde hay 143IRE por volt. Cuando el voltaje de la señal se aproxima a los 100IRE, la imagen se torna brillante, mientras que cuando se aproxima a 0IRE se torna oscura(Fig.5).
Durante el retroceso(momento durante el cual el haz de electrones retrocede hacia la izquierda luego de finalizar el trazado de una línea o hacia arriba luego de finalizar un campo) la señal alcanzará los 0IRE, apagando el haz y haciéndolo invisible.
Conjuntamente con cada línea de video se transmite un pulso de sincronismo horizontal que le permite ser ubicada correctamente en la pantalla, estos pulsos de sincronismo son transmitidos precisamente durante los intervalos de retroceso de línea, alcanzado estos los -43IRE.

La información de color es transmitida sobre una sub-portadora que dista 3.58Mhz de la portadora de video monocromática.
Su amplitud y fase determinan las características cromáticas de la imagen, por un lado la variación de su amplitud da la idea de profundidad(variación de la saturación del color), donde mayor será la saturación cuanto mayor sea la amplitud de la sub-portadora
, por otro lado el color de la imagen dependerá de la fase de esta sub-portadora.
Para determinar el color de la imagen y su saturación, los televisores realizan una comparación de la amplitud y fase de la sub-portadora de color con una referencia. Esta referencia es llamada burst y es transmitida durante el periodo de retroceso horizontal, mas precisamente sobre el pórtico trasero.
En lo que a la información de audio respecta, su transmisión se realiza modulando en frecuencia una portadora que dista 4.5Mhz de la portadora de video monocromática, no difiriendo significativamente de lo que es una transmisión radial de FM.
La relación entre las componentes de una señal de video Pal son complejas, frágiles e importantes. El decodificador debió ser cuidadosamente diseñado y armado de manera que estas relaciones permanezcan lo mas intactas posibles(ver conclusión).
A continuación se da una descripción mas detallada de los niveles y tiempos establecidos por la norma.

1.2- Características de la señal de video

Numero de líneas por cuadro: 625
Numero de campos por segundo: 50
Frecuencia de línea: 15625Hz  0.00014%
Periodo nominal de línea(H): 64s
Periodo nominal de campo: 20ms
Gamma supuesta del dispositivo: 2.8
Ancho de banda nominal del dispositivo: 4.2Mhz
1.3- Detalles del sincronismo de línea

a- Intervalo de supresión de línea: 120.3s
b- Duración del pórtico delantero: 1.50.3s
c- Duración del pulso de sincronismo horizontal: 4.70.2s
d- Tiempo de establecimiento del pulso de supresión: 0.30.1s *
e- Tiempo de establecimiento del pulso de sincronismo horiz: 0.20.1s *
f- Tiempo de comienzo del burst: 5.60.1s
g- Duración del burst (91ciclo): 2.510.28s

1- Nivel de supresión: 0 IRE
2- Nivel de blanco máximo: 100 IRE
3- Nivel de sincronismo: -43 IRE
4- Diferencia entre el nivel de negro y el de supresión: 0 IRE
5- Nivel de pico a pico del burst: 405 IRE

1.4- Detalles del sincronismo de campo
h- Período de supresión de campo: 25H+a
i- Duración de la secuencia de pre-ecualización: 2.5H
j- Duración de la secuencia de sincronismos verticales: 2.5H
k- Duración de la secuencia de pos-ecualización: 2.5H
l- Duración del pulso de ecualización: 2.350.1s
m- Duración del pulso de sincronismo vertical: 27.3s
n- Intervalo entre pulsos de sincronismo vertical: 4.70.2s
o- Tiempo de establecimiento de los pulsos de
sincronismo vertical y de ecualización: 0.20.1s *


(*)-Los tiempos de establecimiento fueron tomados entre el 10% y 90% de los bordes de pulso.

Capitulo 2:
La codificación actual


2.1- Codificación del sincronismo horizontal.

Esta es la mas evidente sobre la pantalla e involucra 2 de los 4 métodos para lograr su efecto. El primer método consiste en realizar una atenuación aleatoria (0,6 o 10db) de los pulsos de sincronismo horizontal (el burst también es afectado).
Como se puede ver(Fig.12), el hecho de que el sincronismo sea atenuado ocasiona que este quede inmerso junto con la información de video.
De esta manera el separador de sincronismos del tv o vcr no puede realizar una separación efectiva de los mismos y toma video como si fuese sincronismo, generando falsos pulsos de sincronismo que se evidencian como desgarros en la imagen.
El segundo método se denomina split-sync o sincronismo rasgado y consiste en partir (2.2uSeg aprox.) los pulsos de sincronismo horizontal, invirtiendo la segunda parte de los mismos.
De esta manera no solo se afecta su amplitud, sino también su duración, haciéndolos mas difícil de detectar, dado que en los procesadores de video utilizados en los tv modernos los pulsos son reconocidos por su duración, descartándoselos si esta no es la correcta.Siendo que los desgarros de la imagen dependen de la información de video transmitida, si esta resultase de baja amplitud, el separador puede que pierda los pulsos de sincronismo reales, pero no generará falsos pulsos, en este caso todo dependerá de la estabilidad del oscilador horizontal. Si el tv es moderno, puede que utilice un resonador cerámico, resultando un corrimiento de frecuencia muy leve y la imagen entonces será perfectamente discernible. Para evitar este tipo de situaciones se implementan los 2 próximos métodos.
Esta se reconoce fácilmente ya que cuando la imagen esta invertida, se obtiene su negativo(lo blanco pasa a ser negro y viceversa).La inversión solo afecta la información de video (no los sincronismos), los tiempos en los que la imagen permanece normal o invertida varían aleatoriamente.


2.3- Codificación del sincronismo vertical.

Esta técnica fue la ultima en implimentarse y consiste en atenuar aleatoriamente en 0,6 o 10db tanto los pulsos de pre y pos-ecualización como los pulsos de sincronismo vertical, de esta manera el sincronismo vertical queda inmerso en el video (Fig.16), resultando que en el mejor de los casos (imagen sin desgarros), el sincronismo vertical no pueda ser recuperado y la imagen rote verticalmente.
Los decodificadores oficiales para la detección y recomposición del mismo, se basan en un pulso denominado gatillo vertical (Fig.17), que es transmitido por el canal de audio (en banda base).
La etapa decodificadora a realizar, no hace uso de esta señal ya que el principio de funcionamiento adoptado no lo requiere, por otro lado, la idea no es la de copiar el funcionamiento de una placa decodificadora oficial.


2.4- Señalización de control.

Anteriormente se dijo que tanto el modo de video como el grado de atenuación de los sincronismos (H y V) variaba aleatoriamente, en realidad no hay nada de aleatorio.La información de control necesaria para la recomposición de la señal es codificada en una palabra binaria, la cual es enviada sobre una de las primeras líneas de video, recordemos que las líneas 1 a 23 son transmitidas en negro o se utilizan para enviar información a los operadores de cable(teletexto).
En el sistema actúa, para ser mas exactos sobre las líneas 6 del campo1 y 319 del campo2, se codifican mediante ráfagas (3.58Mhz) de corta (0) o larga (1) duración el grado de atenuación de los sincronismos que se esta utilizando actualmente (0,6 o 10db) y el modo de video(normal/invertido).
La etapa decodificadora a diseñar no hace uso de esta información, basando su funcionamiento en otras señales que será tratadas en su momento.
De esta manera se logra simplificar tanto la circuiteria como la lógica.


2.5- Codificación del audio.

La codificación realizada sobre de audio consiste básicamente en un desplazamiento frecuencial del canal mismo, a una frecuencia de 31.25Khz(2xfhoriz).
Esto se logra utilizando la información de audio para modular en frecuencia una portadora de 31.25Khz, obteniéndose el siguiente especto.
Como se puede ver en la Fig.20, la banda base del canal de audio es utilizada para mandar información, en este caso, el pulso de gatillo vertical que según se dijo no será utilizado. Este pulso es reconocido fácilmente, ya que al recibirse un canal codificado se escuchará un zumbido de baja frecuencia por los parlantes, mientras que la portadora de 31.25Khz esta fuera del rango de audición.
Capitulo 3:

Diseño de la etapa decodificadora

La idea en torno a la cual gira el diseño de la etapa decodificadora de video consiste en generar un cuadro perfectamente sincrónico al de la señal codificada,
posteriormente sobre este se ira “pegando” el burst y las líneas de video, invirtiéndolas o no según corresponda. Para generar este cuadro, se deben crear los pulsos de sincronismo horizontal y vertical mas los de pre y pos-ecualización, debiéndose cumplir en todo momento con los niveles y tiempos especificados por la norma Pal-N.
Siendo que se desea lograr un bajo costo, la cantidad de componentes deberá de ser la mínima, razón por la cual se opto por la utilización de un microcontrolador (c), mientras que el resto de la circuiteria proveerá a este de la información necesaria para reconstruir el video.


3.1- Sincronización de cuadro

Bien, lo primero que debe hacerse entonces es sincronizarse con el cuadro de la señal codificada, pero resulta que los pulsos de sincronismo de esta están “codificados”, por lo que un circuito detector de sincronismo convencional no podrá ser utilizado, por otro lado, a modo de referencia se pudo haber utilizado el burst, pero esto hubiese incrementado sin duda el costo del proyecto, por lo que se debió buscar otra referencia (tal vez no tan evidente) dentro de la señal de video.
Como se pudo ver anteriormente, los pulsos de sincronismos a diferencia de la información generalmente transmitida durante una línea de video convencional, se caracterizan por alcanzar transiciones de hasta 200nseg. Estas transiciones (flancos positivos y negativos) pueden ser usadas como referencia para posibilitar la sincronización de los 2 campos. El siguiente circuito se implemento para la detección de las mismas.
En la Fig.22 se representan las salidas de los detectores, se puede ver que el split-sync produce flancos positivos (aislados del resto) que pueden ser perfectamente detectados por el c.
La información obtenida hasta el momento no es suficiente, ya que solo basándose en los flancos producidos por el split-sync el c no tiene forma de saber que línea o campo se esta transmitiendo.
En la Fig.23 se representan las salidas de los detectores de flancos durante el retroceso vertical, como se puede ver, la señal entregada por el detector de flancos positivos se caracteriza por poseer 2 flancos muy próximos, separados aprox. 7s (Fig.24), estos flancos solo son producidos durante la línea 3 del campo1 o la línea 315/316 del campo2 (ver Fig.1).
Bastara entonces solo determinar en que campo se está, para saber que línea es, sabiendo el numero de línea, el c puede ya comenzar a trazar un cuadro sincrónico al codificado.

S2
btfss PORTB,POS ; Espera flanco POS (t=0)
goto S2
nop
movf PORTB,W ; Detecta ausencia de flancos
iorwf PORTB,W
iorwf PORTB,W ; en VBI (nivel alto)
movwf DataSample
btfsc DataSample,NEG ; si hay un flanco POS
goto SEARCH ; recomenzar
btfsc DataSample,POS ; si hay un flanco NEG
goto SEARCH ; recomenzar
movf PORTB,W ; Detecta si hay un flanco NEG (+4.4)
movwf DataSample
btfss DataSample,NEG ; si no es NEG
goto SEARCH ; recomenzar
nop
nop
movf PORTB,W ; Detecta si hay un flanco POS (+2.4)
movwf DataSample ; (inicio de pos-eq)
btfss DataSample,POS ; si no es POS
goto SEARCH ; recomenzar
movlw 49 ; delay
movwf Loops

Para saber de que campo se trata, el c espera (a partir del siguiente flanco positivo) dos líneas y medias, en este punto, si detecta un flanco negativo (fin línea 5)
el campo es el 1, de no detectarse el flanco (mitad línea 318) el campo era el 2 y el proceso de búsqueda recomienza.

movf PORTB,W ; Detecta si hay un flanco NEG (+96)
movwf DataSample ; (fin linea 5)
btfss DataSample,NEG ; si no es NEG
goto SEARCH ; recomenzar
movlw 46 ; delay
movwf Loops
S5
decfsz Loops,1 ; 45*1.2+0.8=54.8
goto S5
bcf VideoMode,FIND ; Linea 3 encontrada
retlw 1
La sub-rutina de búsqueda SEARCH es quien se encarga de realizar el procedimiento anterior, esta es la primera que se ejecuta ni bien se inicializa el c y solo se retorna de la misma cuando la línea 3 ha sido hallada.


3.2- Rutina principal

Una vez hallada la línea 3, la sub-rutina de búsqueda finaliza y devuelve el control del programa a la rutina principal MAIN. Esta se encarga de llamar a las diferentes sub-rutinas que irán creado el cuadro.

nop
btfsc VideoMode,FIND ; si hay error de sync
call SEARCH ; re-sync
movlw 16
movwf LineaCnt
call HORLINEA ; Lineas 7 a 22

nop
nop
nop
bcf VideoMode,BLK ; deshabilito black video
movwf LineaCnt
call HORLINEA ; Linea 23

bcf VideoMode,INV ; no invertir video
btfsc DataSample,POS ; Auto-inversion (inico linea 23)
bsf VideoMode,INV ; si hay flanco POS=>invertir video
movlw 200
movwf LineaCnt
call HORLINEA ; Lineas 24 a 223

nop
nop
nop
movlw 82
movwf LineaCnt
call HORLINEA ; Lineas 224 a 305

nop
nop
bsf VideoMode,BLK ; habilito black video
movlw 5
movwf LineaCnt
call HORLINEA ; Lineas 306 a 310

goto MAIN ; al CAMPO 2

Las sub-rutinas de las cuales hace uso son: HORLINEA
MEDLINEA
VBI
MODE

A continuación se explica en detalle cada una de estas.


3.3- Creación del cuadro

Como se dijo anteriormente el sincronismo horizontal sufre una doble codificación, para la restauración del mismo se debería implementar un circuito capaz de recuperar la información transmitida sobre la línea 6 o 319 (grado de atenuación actual) y un circuito atenuador controlado para recomponer el mismo, esto no solo incrementaría el costo sino también la complejidad de la etapa.
Dado que la restauración del sincronismo horizontal no es rentable, se optó por crearlo.La creación, tanto de los pulsos de pre/pos-ecualización como de los pulsos de sincronismo horizontal/vertical, será realizada por el c en base al manejo de dos niveles de tensión (nivel de negro y nivel de sync) y a un control riguroso de sus tiempos. El circuito implementado fue el siguiente:
Como se puede ver R32 y R33 constituyen un divisor resistivo, según el c lleve R31 a masa o Vcc, se obtendrá el nivel de sync o el nivel de negro. Cuando estos son requeridos la llave Vnegro/sync es accionada.
La siguiente figura ilustra la señal de control sobre R31:
De esta manera, mediante el manejo de la llave y niveles(negro y sync) el c genera los nuevos pulsos de sincronismo horizontal que reemplazan a los originales (codificados).
El accionamiento conjunto de las llaves Vburst y Vnegro/sync (en el instante adecuado) posibilita un correcto “pegado” de la señal de burst sobre el nivel de negro del pórtico trasero.


3.4- Inserción de línea

La sub-rutina HORLINEA es la mas utilizada y sin duda la mas importante. La misma por un lado crea el pórtico delantero, el pulso de sincronismo horizontal y el pórtico trasero, además realiza la inserción del burst y la línea de video (invertida o no, según corresponda).

Por otro lado se encarga de comandar el VCXO (externo), posibilitando una resincronización línea a línea y asegurando así una imagen perfectamente estable.



HORLINEA ; t=-4.4
nop
movlw MAKEBLACK
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Portico delantero=2.4us
; t=-2.4
nop
nop
movlw MAKESYNC
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Ventana sync=4.4us
; t=0
nop
nop
nop
nop
movf PORTB,W ; t=2 (Split-Sync)
movwf DataSample ; tomo muestra para re-sincronizacion
nop
movlw PASSBURST
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Ventana burst=5.6us

Como se puede ver tanto los pórticos como el pulso de sincronismo horizontal se crean según se explico antes, mediante un riguroso control de tiempo de los niveles de sync y negro, luego mediante la acción conjunta de las llaves Vburst y Vnegro/sync, se inserta el burst. El tipo de línea dependerá del modo de video seleccionado, pudiendo insertarse una línea normal, invertida o en negro.

movlw PASSVIDEO
btfsc VideoMode,INV ; control de inversion
movlw PASSINVER
btfsc VideoMode,BLK
movlw MAKEBLACK
btfss VideoMode,DEC
movlw PASSVIDEO

La inserción de líneas normales o invertidas, depende del estado del flag INV, el cual es actualizado desde MAIN, según el estado de la línea 23.
Cuando se requieren líneas en negro (ej: primeras líneas de cada campo), se activa el flag BLK, el cual también es actualizado desde MAIN.
El flag DEC, es actualizado desde MODE, dependiendo principalmente del estado de la entrada de habilitación manual (pin2). Al deshabilitarse la etapa, las señales de audio y video no son procesadas, pasando sin ser modificadas hacia la salida.
La cantidad de líneas a realizar depende de LineaCnt, HORLINEA se re-ejecutará hasta que LineaCnt sea 0, retornándose hacia MAIN al finalizar.

decf LineaCnt,f
btfsc STATUS,Z ; Si LineaCnt=0
; t=56
retlw 1 ; retornar a MAIN
nop ; delay antes de recomenzar otra linea
nop
nop
nop
nop
nop
goto HORLINEA ; crear otra linea



Dado que la cantidad de líneas por campo no es un numero entero, se implementó la sub-rutina MEDLINEA para el trazado de medias líneas, mas específicamente la línea 623 a 623,5. El proceso es igual que en HORLINEA, finalizado el pórtico delantero, se crea el pulso de sincronismo horizontal, luego se inserta el burst sobre el pórtico trasero y la línea de video (que en este caso, corresponde al nivel de negro), al finalizar se retorna a MAIN.

MEDLINEA ; t=-4.4
movlw 2 ; delay
movwf Loops
ML1 ; t=-3.6
decfsz Loops,f ; 1*1.2+0.8=2
goto ML1
movlw MAKESYNC
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Ventana sync=4.4us
; t=0.0
movlw 2 ; delay
movwf Loops
ML2 ; t=0.8
decfsz Loops,f ; 1*1.2+0.8=2
goto ML2
movlw PASSBURST
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Ventana burst=5.6us
; t=4.4
movlw 3 ; delay
movwf Loops
ML3 ; t=5.2
decfsz Loops,f ; 2*1.2+0.8=3.2
goto ML3
movlw MAKEBLACK
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Black video
nop
movlw 11 ; delay
movwf Loops
ML4 ; t=11.2
decfsz Loops,f ; 10*1.2+0.8=12.8
goto ML4
retlw 1


Desde el punto de vista del hardware, las señales de video normal e invertida son tomadas sobre el emisor y colector de TR2 respectivamente, estas no solo son opuestas en fase, sino que poseen ademas diferentes niveles de DC. Para una correcta inserción, las líneas de video normales e invertidas deben poseer el mismo nivel de DC (un mismo brillo), para unificar los niveles de DC se implementó el siguiente circuito, accionado por el c solo durante la inserción de línea.
Ahora ambas líneas (normales/invertidas) son llevadas a un mismo nivel de DC (nivel de pegado) que es aprox. Vcc/2.
En el canal 2 se puede ver la señal que acciona el nivel de pegado (Clamp) y en el canal 1, las líneas ya insertadas.


3.5- Resincronización de línea

El reloj del c tiene como base un cristal de 10Mhz, por lo cual el tiempo de ejecución de cada instrucción es de 400ns excepto saltos(800ns).
En base a estos tiempos se escribió el programa para obtener pulsos de sincronismo espaciados 64s, lográndose una frecuencia de línea de 15625Hz, según la norma Pal-N lo establece. Luego, una vez obtenido el sincronismo de la señal codificada, estos mismos pulsos reemplazarán a los codificados.
Teniendo en cuenta que la frecuencia de línea de las estaciones de tv difieren levemente y si a esto se suman posibles inestabilidades en la base de tiempo (ej: efectos de la temperatura) es probable que se obtenga un funcionamiento inestable de la etapa.
En un principio se penso en una solución por software, implementada en base a “saltos” de instrucciones con el objeto de reducir o incrementar el tiempo de línea, el problema radico en que el salto mínimo hubiese sido de 800ns, lo cual sobre 64s (1 línea) ocasiona efectos visibles sobre la imagen (temblores) por lo que se descarto esta posibilidad.Se recurrió entonces a la implementación por hardware de un VCXO (digital), que incremente o reduzca la frecuencia de línea con una mayor resolución.
El XTAL, C13 y C15 constituyen el reloj básico utilizado por el c, C14 en paralelo con el XTAL, permite ajustar la frecuencia central de oscilación.

; t=0
nop
nop
nop
nop
movf PORTB,W ; t=2 (Split-Sync)
movwf DataSample ; tomo muestra para re-sincronizacion
nop
movlw PASSBURST
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Ventana burst=5.6us
; t=4.4

La resincronización de línea se basa en el flanco positivo producido por el split-sync, el mismo es muestreado en cada línea, el hecho que no se detecte implica que la frecuencia de línea es alta, debiéndose bajar (OSCTRLON), si es detectado implica que la frecuencia es baja, debiéndose subir (OSCTRLOFF), de esta forma se hace trabajar al VCXO alternadamente entre estas 2 frecuencias, alcanzando su funcionamiento optimo y una imagen perfectamente estable.

nop
bcf PORTA,0
movlw OSCTRLON
btfsc DataSample,POS ; Si hay un flanco POS
movlw OSCTRLOFF ; subir frec.
tris PORTA ; habilitar osc. control

La corrección de frecuencia es realizado por C12, mediante la acción del pin12, según se necesite reducir o aumentar la frecuencia de línea, el c reducirá o aumentará la frecuencia de reloj, conectando o desconectando C12 en paralelo con C13.
Si bien la corrección es ínfima, del orden de 25 ppm, esta es necesaria para mantener un cuadro estable, la misma solo se realiza durante el tiempo en que la línea esta activa, al finalizar esta, el VCXO siempre es deshabilitado (OSCTRLOFF).

movlw OSCTRLOFF
tris PORTA ; deshabilitar osc. control
bcf PORTA,4 ; test port off

El pin3 (TP), refleja el estado del VCXO, siendo útil a la hora de calibrar C13, considerando que el punto optimo se alcanza cuando el VCXO trabaja alternadamente (on-off-on.....) línea a línea.
3.6- El retroceso vertical

La sub-rutina activa durante del retroceso vertical es VBI, quien cumple una doble función, por un lado crea los pulsos de sincronismo vertical y los de pre/pos-ecualización en base al manejo de tiempos de los niveles de negro y sync (ídem sincronismo horizontal).

La sub-rutina comienza con el trazado de los primeros 5 pulsos de pre-ecualización a partir de la línea 623,5 campo1 o línea 311 Campo 2.

VBI ; t=-4.4
movlw 2 ; delay
movwf Loops
V1
decfsz Loops,f ; 1*1.2+0.8=2
goto V1
PREEQ
movlw MAKESYNC
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Ventana SYNC=2.4us
; t=0
nop
nop
movlw MAKEBLACK
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Black video=29.6us
nop
nop
movlw 21
movwf Loops
V2 ; t=4
decfsz Loops,f ; 20*1.2+0.8=24.8
goto V2
movlw 5 ; cantidad de pulsos proximos
decfsz LineaCnt,f
goto PREEQ
movwf LineaCnt

Por otro lado la sub-rutina chequea si el campo codificado y el creado están correctamente sincronizados, esto lo realiza mientras se crean los pulsos de sincronismo vertical, en base a muestras tomadas durante las líneas 1 a 3,5.


VSYNC
movlw MAKESYNC
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Ventana SYNC=27.2us
movf PORTB,W
iorwf PORTB,W
nop
movwf DataSample
btfss DataSample,NEG ; si no es NEG
bsf VideoMode,ERR ; error de sincronismo
movlw 19 ; delay
movwf Loops
V3
decfsz Loops,f ; 18*1.2+0.8=24.8
goto V3
movlw MAKEBLACK
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Black video=4.8us
nop
nop
nop
nop
movlw 5 ; cantidad de pulsos proximos
decfsz LineaCnt,f
goto VSYNC
movwf LineaCnt

Como se puede ver las muestras son tomadas durante las transiciones negativas.
De existir una correcta sincronización el c detectara los pulsos producidos por el campo codificado, de no ser así, se activara el flag de ERR quien es chequeado por la sub-rutina MODE.

POSEQ
movlw MAKESYNC
btfss VideoMode, DEC
movlw PASSVIDEO
movwf PORTB ; Ventana SYNC=2.4us
; t=0
nop
nop
movlw MAKEBLACK
btfss VideoMode,DEC
movlw PASSVIDEO
movwf PORTB ; Black video=29.6us
movlw 17 ; delay
movwf Loops
V4 ; t=2.8
decfsz Loops,f ; 16*1.2+0.8=20
goto V4
decf LineaCnt,f
btfsc STATUS,Z
retlw 1 ; sale de VBI
movlw 4 ; delay
movwf Loops
V5
decfsz Loops,f ; 3*1.2+0.8=4.4
goto V5
goto POSEQ

Los últimos 5 pulsos de pos-ecualización son creados de igual manera que los de pre-ecualización, retornándose al finalizar hacia MAIN (Línea 6 Campo1 o Línea 318,5 Campo2).






3.7- Drivers Entrada/Salida
La configuración de los drivers de entrada y salida es la misma, esta consiste de 2 transistores realimentados, de manera de obtener baja distorsión y el ancho de banda suficiente como para trabajar con señales de video. Su principal función es la de acoplar la etapa decodificadora, por un lado a la fuente de señal(VCR) y por otro al TV.
Mediante RV1 se ajusta el nivel de señal de entrada, el cual deberá estar entre 0.5 y 1.5Vpp para un correcto funcionamiento.
La ganancia para los puntos A y B es de 0.5, obteniéndose en estos la señal de entrada invertida (A) y no invertida (B), luego dependiendo del modo de video, el c seleccionará una dándole paso a través de la llave Vnorm o Vinver.
La señal de burst y de sincronismo es tomada del punto C, la ganancia en este punto es 1.5, asegurando así que en las peores condiciones(atenuación 10db) no se pierda el sincronismo. C10 y R20 conforman un filtro pasa altos, por el que solo progresan las transiciones rápidas que disparan los detectores de flancos.
Este otro driver, fue modificado para obtener baja impedancia de salida y una ganancia fija de 2, el nivel de señal de salida esta dado por RV2, quien se ajusta una vez instalada la etapa.

3.8- Control de inversión
En el sistema actual, según se dijo, la información de control se transmite sobre las líneas 6 (campo1) y 319 (campo2). Esta información esta codificada mediante ráfagas de 3.58Mhz, donde dependiendo de la duración de las mismas representan un 0 o un 1, estos a su vez constituyen una palabra binaria que le indica al decodificador oficial el grado de atenuación (0,6o10db) y el modo de video actual (normal/invertido).
Dado que se opto por regenerar el sincronismo horizontal y vertical, la información de atenuación no es necesaria, mientras que el modo de video se determinó de la siguiente manera.

Como se puede ver, parte de la primer línea activa de video (línea 23) es siempre transmitida en negro, el hecho de que esté codificada ocasiona que pierda su nivel de DC y quede inmersa junto con el resto del video codificado, el detector de flancos positivos reportará esto mediante un pulso que es fácilmente visto por el c.

movwf PORTB ; comienzo de la linea de video
movf PORTB,W ; muestras para auto-inversion
iorwf PORTB,W
movwf DataSample
Dado que la línea 23 esta siendo afectada por la codificación, de producirse una inversión de video, esta será invertida.
Ahora el flanco positivo no se producira, delatando la inversión. En base a esto el c maneja las llaves Vnorm y Vinver (video normal/invertido), compensando las inversiones.

bcf VideoMode,INV ; no invertir video
btfsc DataSample,POS ; Auto-inversion (inico linea 23)
bsf VideoMode,INV ; si hay flanco POS=>invertir video
movlw 200
movwf LineaCnt
call HORLINEA ; Lineas 24 a 223

3.9- Habilitación de la etapa

La sub-rutina MODE se encarga de habilitar la decodificación en base a la información provista desde VBI (a través del flag de ERR), o dependiendo del estado de la entrada de habilitación manual ( 1-habilitacion / 0-deshabilitacion).
Esta sub-rutina es ejecutada una vez por cuadro, durante la transmisión de la media línea 318,5 a 319.

MODE ; t=-4.4
btfss PORTA,3 ; habilitacion manual
bsf VideoMode,ERR ; si RA3=1
btfss VideoMode,ERR ; si no hay error de Vsync
clrf CntSyncErr ; borrar contador de cuadros malos
incf CntSyncErr,f ; incrementar contador de cuadros malos
btfsc CntSyncErr,2 ; si hay 4 cuadros malos consecutivos
bcf VideoMode,DEC ; dejar de decodificar
btfsc CntSyncErr,2 ; si hay 4 cuadros malos consecutivos
bsf VideoMode,FIND ; buscar Linea 3
btfsc CntSyncErr,2 ; si hay 4 cuadros malos consecutivos
clrf CntSyncErr ; recomenzar la cuenta de cuadros malos
incf CntSyncOk,f ; incrementar cuadros buenos
btfsc VideoMode,ERR ; si hay error de Vsync
clrf CntSyncOk ; recomenzar la cuenta de cuadros buenos
btfsc CntSyncOk,2 ; si hay 4 cuadros buenos consecutivos
bsf VideoMode,DEC ; comenzar la decodificasion
bcf VideoMode,ERR
De estar en alto la entrada de habilitación manual y solo si los últimos 4 cuadros de video estuvieron correctamente sincronizados (ERR=0), se procede a habilitar la decodificación (DEC=1) tanto de audio como de video y el led D4 es encendido.

bcf PORTA,1 ; apagar LED
btfsc VideoMode,DEC ; si se habilita la decodificasion
bsf PORTA,1 ; prender LED
bsf PORTA,2 ; deshabilitar deco de audio
btfsc VideoMode,DEC ; si se habilita la decodificasion
bcf PORTA,2 ; habilitar deco de audio

De existir un error de sincronismo (ERR=1), la etapa es deshabilitada (DEC=0), el led es apagado, el video/audio pasan sin ser procesados y el flag FIND es activado, ocasionando que SEARCH sea llamada al retornarse a MAIN.

nop
btfsc VideoMode,FIND ; si hay error de sync
call SEARCH ; re-sync
movlw 16
movwf LineaCnt
call HORLINEA ; Lineas 7 a 22
4.1- Decodificador de audio

La decodificación del audio es relativamente sencilla, para realizar la misma se usó un detector de FM, implementado en base a un PLL.
El PLL utilizado fue el CD4046, cuyo diagrama interno se ilustra a continuación:
El principio de funcionamiento es simple: El lazo cerrado de control hace que el VCO siga las variaciones de frecuencia de la señal de entrada, a su vez estas variaciones de frecuencia dan origen a variaciones de la tensión de error. Esta tensión de error es justamente quien refleja la información de audio.
Dado que el PLL trabaja con señales de entrada cuadradas, la portadora de audio (31.25Khz) deberá ser recuadrada, para esto se utiliza TR5, mientras que C19 solo posibilita el paso de alta frecuencia, bloqueando al señal de gatillo vertical o cualquier otra modulación de baja frecuencia sobre la portadora de audio.
Luego de que la portadora ingresa al PLL (pin14), esta es tomada por los comparadores de fase. El 4046 dispone de 2 comparadores, se utilizo el comp1 debido principalmente a su alta inmunidad al ruido. Al comp1 también ingresa la salida del VCO (pin4) de esta forma luego de la comparación se obtiene la tensión de error, que por un lado reingresa al VCO de manera de ejercer una acción correctiva y por otro lado es entregada a un seguidor emisivo que constituye el driver de salida (pin10).
Este PLL dispone también de una entrada de habilitación (pin5), la cual es controlada por el c (pin1).
Cuando el deco no esta habilitado, el c mantiene la pata 5 en un nivel alto, de esta forma, se inhibe al PLL y se polariza en directa a D5 quien proveerá un camino alternativo a la señal de audio entrante (no se decodifica el audio).
Al habilitarse el deco, la pata 5 se lleva a un nivel bajo habilitando el PLL, siendo que el valor de DC del pin10 es de Vcc/2, D5 ahora es polarizado en inversa y no ejerce acción alguna. R38 y C22 conforman el filtro de salida, limpiando la señal de posibles residuos de portadora.
El voltaje de control aplicado el VCO (pin9) puede ir desde 0v hasta la tensión de alimentación, yendo la frecuencia de salida (pin4) de un mínimo a un máximo.
El rango de frecuencias de trabajo se determina mediante las siguientes fórmulas aproximadas:

Fmin= 1 Fmax=Fmin + 1 .
R40.C21 R39.C21

Luego la frecuencia de corrida libre estará dada por:

Fo Fmax + Fmin la cual debe ser 31.25Khz
2

Adoptando R39=22k y C21=1nf se tiene:

Fmax=Fmin + 45.454Khz  Fo= 2.Fmin + 45.454Khz
2

Fmin=Fo - 45.454Khz =8522.7Hz resultando
2
Fmin=8.3Khz
R40= 1 =117.3k Adopto 120k  Fmax=53.787Khz
Fmin. C21 Fo=31.06Khz

El rango de enganche (Fl), es:

Fl=Fmax - Fmin = 22.7Khz
2
Lo cual resulta aceptable el ser  que 15Khz.


4.2- Modificación del control automático de ganancia

Para un correcto funcionamiento de la etapa decodificadora deberá realizarse previamente una modificación del circuito de AGC (generalmente ubicado en la etapa que realiza el procesamiento de la señal de IF), el motivo de esta reforma y como se realiza la misma, se explican a continuación:
Dado que los pulsos de sincronismo horizontal están siempre presentes, se los toma como referencia de amplitud en todas las normas con modulación inversa de video (NTSC, PAL-N/B/M).
La función del AGC es la de asegurar una señal de video compuesto relativamente estable en amplitud, los circuitos de AGC realizan su acción de control en base a la amplitud de los pulsos de sincronismo horizontal. De esta forma la ganancia de la etapa de IF es función inversa de la tensión alcanzada sobre un capasitor (Cx) cuya carga es realizada mediante un gatillado sincrónico a dichos pulsos. La constante de carga de Cx es relativamente pequeña de unos 10H (640s).

Al tratar con señales codificadas donde el sincronismos horizontal esta atenuado, se produce una inmersión de los pulsos hacia la zona de video, ocasionando que estos no puedan ser correctamente detectados, como consecuencia el AGC de la IF de video realizará modificaciones de la ganancia en base a la información de video, la cual es de carácter aleatorio(Fig.39).

Como resultado de la acción del AGC, la señal es deformada, lo que se manifiesta mediante la aparición de franjas de distintos brillos sobre la imagen, también (dependiendo del tipo de AGC utilizada) si el grado de carga en Cx es bajo, la ganancia de la IF será alta llegando incluso a saturar, de ser así se observarán franjas grises o negras en los subtítulos o en otras partes brillantes de la imagen (la señal de audio también es afectada por la saturación).
La solución a estos inconvenientes consiste en hacer Cx unas 100 o 200 veces mayor, de esta manera se aumenta la cte. de tiempo y el AGC se hace insensible a rápidas variaciones, estabilizando la ganancia.
En caso de que la ganancia resultante sea alta puede que la IF sature, para evitar esto se debe de colocar en paralelo con Cx una resistencia que reduzca la ganancia a un valor adecuado, el valor de la misma se determina experimentalmente, ya que cada tipo de IF presenta su propia impedancia y corriente de carga en el pin de AGC.
En ciertos casos suscede que al aumentar la cte. de tiempo del AGC, el tiempo de encendido del TV o VCR también se incrementan pudiendo ir de 5seg a 2.5min inclusive, dependiendo del nuevo valor de Cx.
Para estos casos se implemento el siguiente circuito:
La función del mismo consiste en aplicar inicialmente un impulso de corriente a Cx, acelerando su carga, luego al cargarse Ca (mediante Ra) se auto-desconecta.
Realizadas estas modificaciones aseguramos una señal estable y clara a la salida del demodulador, la cual se aplicara posteriormente a la entrada de la etapa decodificadora.
4.3- Conexionado y calibración de la etapa

Luego de montado y chequeado el circuito, se coloca el mismo dentro de un gabinete y se procede a su conexionado a través de fichas RCA, estándares en la mayoría de las entrada/salidas de TV y VCR.
Las salidas de audio/video de la VCR deberán conectarse a las entradas de audio/video del deco y las salidas audio/video del deco a las entradas audio/video del TV.
Luego de energizar el deco con una fuente de 9 o 12v (*1), se sintoniza en la video el canal a decodificar (*2), mientras que en el TV se debe seleccionar la entrada auxiliar (A/V). De estar todo correctamente armado, se debe ver en la pantalla de TV la imagen del canal seleccionado (puede que todavía permanezca codificada).
Para un correcto funcionamiento se debe medir la señal de video a la salida de la VCR (habiendo previamente modificado su AGC), el nivel de la misma deberá estar entre 0.5 y 1.5Vpp, dependiendo entonces del nivel de señal, se debe calibra RV1 para obtener a la entrada del deco una señal de 1Vpp.
Posteriormente se procede a ajustar C13 (con un calibrador no metálico), hasta que la imagen sea decodificada (Led encendido) y permanezca estable (*3).
Para realizar una calibración mas precisa se debe medir con osciloscopio la señal en el punto de prueba (TP) e ir regulando C13 hasta obtener la mayor densidad de transiciones posible (ver VCXO).
Hechos estos ajustes la imagen debe verse perfectamente(sin ningún tipo de distorsión), tanto para este canal como para cualquiera de los otros canales codificados, si es que utilizan el mismo método de codificación.
Se dispone además de una entrada de habilitación manual, la etapa esta normalmente habilitada (5v), llevando esta a 0v se deshabilita la misma y las señales de audio/video pasan sin ser procesadas.
El nivel de salida del deco se ajusta mediante RV2, según el requerimiento de señal a la entrada del TV.
Si algunos canales se ven correctamente, mientras que en otros el funcionamiento es intermitente, se puede deber a que:
-La calibración no fue correctamente realizada.
-El AGC no fue correctamente modificado.
-El nivel de señal de video no es el correcto.

(*1)-Según se explico, la etapa se coloca entre la VCR y el TV, alimentada por una fuente externa de 9 o 12v, pero nada evita que la misma pueda ser colocada en el interior de la VCR, considerando que el consumo de la etapa es de 70mA.
(*2)-En los modelos mas nuevos de VCR´s, deberá deshabilitar el “black screen” de manera de obtener la señal de video sobre el conector de salida.
(*3)-En ciertas VCR´s, en las que el nivel de salida es mayor a 1.5Vpp, puede que el deco presente un funcionamiento inestable (debido a una desadaptación de impedancias), se deberá colocar entonces una resistencia de 75 en paralelo con la salida de la video.
4.5- Listado de componentes

Fuente
C1=C2=100f
C3=100nf
D1=1N4001
IC1=LM7805

Deco de Video
R1= R2= R14= R28= R29= C4= C5= C6= C7= C8=47f
R31= RV1= RV2=10k C9=1nf
R3= R4=220 C10=470pf
R5= R15=470 C11=220nf
R6= R18=47 C12=22pf
R7=120 C13=5-20pf
R8=56 C14=18pf
R9= R12= R20= R21= R24= C15=33pf
R25= R26= R27= R30= R33=1k XTAL=10Mhz
R10= R11=470k D2= D3=1N4148
R13=27k D4=Led
R16=82 TR1= TR3=BC548
R17=150 TR2= TR4=BC558
R19=100 IC2=CD4066
R22= R23=10 IC3=LM393
R32=2k2 IC4=PIC16F84

Deco de Audio
R33= R37= R38=10k C18=C23=47f
R34=220k C19= C22=10nf
R35= R36=1k C20=100nf
R39=22k C21=1nf
R40=120k TR5=BC548
IC5=CD4046 D5=1N4148

4.6- Descripción de variables y puertos

Generales
OSCTRLON=Habilitación del VCXO.
OSCTRLOFF=Deshabilitación del VCXO.
NEG=Salida del detector de flancos negativos.
POS= Salida del detector de flancos positivos.
Loop=Contador de ciclos.
LineaCnt=Contador de líneas.
CntSyncOk=Sincronismo de cuadro ok.
CntSyncErr=Error en sincronismo de cuadro.
DataSample=Muestra de dato de línea.
VideoMode=Modo de video actual.

Flags
BLK=Trazar línea en negro.
DEC=Habilitar la decodificación
INV=Invertir línea de video.
ERR=Error de sincronismo.
FIND=Resincronizar.

Llaves
PASSVIDEO=Vnorm+Clamp (Inserta línea normal).
PASSINVER=Vinver+ Clamp (Inserta línea invertida).
PASSBURST=Vburst+N/S+Vnegro/sync (Inserta burst sobre nivel de negro).
MAKESYNC=Vnegro/sync (Crea nivel de sync).
MAKEBLACK=Vnegro/sync+N/S (Crea nivel de negro).

Puerto A
0(pin17)=Control del VCXO.
1(pin18)=Control del Led.
2(Pin1)=Control del deco de Audio.
3(pin2)=Entrada de habilitación manual.
4(pin3)=Punto de calibración (estado del VCXO).

Puerto B
0(pin6)=Control llave de paso de video normal (Vnorm).
1(pin7)=Control del nivel de pegado (Clamp).
2(pin8)=Entrada detector de flancos negativos (NEG).
3(pin9)=Entrada detector de flancos positivos (PED).
4(pin10)=Control de los niveles de Negro(0) / Sync (1)(N/S).
5(pin11)=Control llave de paso de video invertido (Vinver).
6(pin12)=Control llave de paso de Burst (Vburst).
7(pin13)=Control llave de paso de nivel de Negro o Sync (Vnegro/sync).


4.7- Software
 
Estado
Cerrado para nuevas respuestas.
Atrás
Arriba